averageifs,excel按区间计算价格

averageifs，excel按区间计算价格？

若是要做一个图一的折线图，就是要做一个数据结构表，年数和平均单价，另外有一个单元格输入汽车型号，型号可用下拉菜单直接点，平均单价只要用AVERAGEIFS函数即可自动核算，最后根据表格生成图一的图表完成后，只要选择车型，自动生成图一的折线图啦

Excel有哪些和vlookup一样重要的函数或功能？

在Excel中，Vlookup函数的基本功能就是查询引用，请看下文：

一、Vlookup函数：功能及语法结构。

功能：在指定的数据范围内返回符合查询要求的值。

语法：=Vlookup(查询值，数据范围，返回值列数，匹配模式)。

其中匹配模式有两种，分别为“0”或“1”。其中“0”为精准匹配，“1”为模糊匹配。

目的：查询“商品”的“销量”。

方法：

在目标单元格中输入公式：=VLOOKUP(H3,B3:C9,2,0)。

解读：

第三个参数（返回值列数）是根据第二个参数（数据范围）来确定的，“数据范围”中的第一列为1，第二列为2……以此类推。

二、Vlookup函数：反向查询。

目的：根据“编码”查询“商品”名称。

方法：

1、在目标单元格中输入公式：=VLOOKUP(I3,IF({1,0},C3:C9,B3:B9),2,0)。

2、Ctrl+Shift+Enter填充。

解读：

公式中的IF({1,0},C3:C9,B3:B9)的作用为形成一个以C3:C9为第一列、B3:B9为第二列的临时数组。

三、Vlookup函数：多条件查询。

目的：根据“商品”名称和“型号”查询“销量”。

方法：

1、在目标单元格中输入公式：=VLOOKUP(I3&J3,IF({1,0},B3:B9&C3:C9,D3:D9),2,0)。

2、快捷键Ctrl+Shift+Enter填充。

解读：

1、当有多个查询的条件时，用连接符“&”连接在一起，对应的数据区域也用“&”连接在一起。

2、公式中IF({1,0},B3:B9&C3:C9,D3:D9)的作用为形成一个以B3:B9和C3:C9为第一列，D3:D9为第二列的临时数组。

四、Vlookup函数：多条件反向查询。

目的：根据“商品”的销售“地区”查询对应的“销量”。

方法：

1、在目标单元格中输入公式：=VLOOKUP(I3&J3,IF({1,0},B3:B9&F3:F9,D3:D9),2,0)。

2、快捷键Ctrl+Shift+Enter填充。

解读：

当有多个条件和数据范围时，对应的值用符号“&”连接。

五、Vlookup函数：屏蔽错误值。

目的：无查询匹配结果时，不显示错误代码#N/A， 将单元格的置空。

方法：

在目标单元格中输入公式：=IFERROR(VLOOKUP(I3&J3,IF({1,0},B3:B9&F3:F9,D3:D9),2,0),"")。

解读：

Iferror函数的作用为：判断一个表达式是否有误，如果有误，则返回本身，否则返回指定的值；语法结构为：=Iferror(表达式,表达式有误时的返回值)。

六、Vlookup函数：批量查询。

目的：根据“商品”名称批量返回相关信息。

方法：

在目标单元格中输入公式：=VLOOKUP($I3,$B$3:$F$9,MATCH(J$2,$B$2:$F$2,0),0)。

解读：

1、巧妙利用Match函数获取返回值对应的列数。

2、注意参数的引用方式，不变为“绝对”、变为“相对”，也可以是“混合引用”。

七、Vlookup函数：一对多查询。

目的：根据对应的值返回多个查询结果。

步骤1：插入辅助列。

方法：

1、在“商品”列的前面插入“辅助列”。

2、输入公式：=COUNTIF(C$3:C3,C3)。

解读：

利用Countif函数统计“商品”在对应的区域出现的次数。

步骤2：根据“商品”名称查询对应的“型号”。

方法：

1、在目标单元格中输入公式：=IFERROR(VLOOKUP($J$3&ROW(A1),IF({1,0},C3:C9&B3:B9,D3:D9),2,0),"")。

2、快捷键Ctrl+Shift+Enter填充。

解读：

公式主要运用了“逆向查询”和“屏蔽错误值”两种主要方法。

步骤3：根据“商品”名称和“型号”查询对应的销量。

方法：

1、在目标单元格中输入公式：=IFERROR(VLOOKUP($J$3&$K3,IF({1,0},C3:C9&D3:D9,E3:E9),2,0),"")。

2、快捷键Ctrl+Shift+Enter填充。

解读：

公式主要应用了多条件的方法。

一、Lookup函数。

Lookup函数具有两种使用形式。

1、向量形式。

功能：是指在单行或单列中查询指定的值，然后返回第二个单行或单列相同位置的值。

语法结构：=Lookup(查询值，查询值所在的范围，[返回值所在的范围])。

前提条件：查询值所在范围的值，必须按照升序排序，否则无法得到正确的结果。

目的：查询销售员的销量。

方法：

1、以“销售员”为主要关键字进行升序排序。

2、在目标单元格中输入公式：=LOOKUP(H3,B3:B9,D3:D9)。

解读：

1、由于Lookup函数本身的特点，在查询一用之前，必须对查询范围的值进行升序排序，否则无法得到准确的查询结果。

2、当查询范围和返回返回相同时，返回范围可以省略哦！

2、数组形式。

作用：在对应的数据源中的第一列或第一行中查找值，并返回最后一列或最后一行对应的值。

语法结构：=Lookup(查询值，查询值和返回值所在的范围)。

前提条件：查询值所在范围的值，必须按照升序排序，否则无法得到正确的结果。

目的：查询销售员的销量。

方法：

1、以“销售员”为关键字进行升序排序。

2、在目标单元格中输入公式：=LOOKUP(H3,B3:D9)。

解读：

1、由于Lookup函数本身的特点，在查询一用之前，必须对查询范围的值进行升序排序，否则无法得到准确的查询结果。

2、使用数组形式时，查询值范围必须在第一列，返回值范围必须在最后一列哦！

3、单条件查询。

在实际工作中，数据源中的数据不可能按照升序有序排列，难倒就不能用Lookup函数查询引用了吗……为了解决这一难题，Lookup衍生出了“变异用法”。

目的：查询销售员的销量。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B9=H3),D3:D9)。

解读：

1、在学校Lookup函数的基础语法时，已经强调过，要向得到正确的查询结果，必须对查询值所在范围的值进行升序排序，但在“单条件”查询时，并未对查询值所在范围的值进行升序排序，而是采用了奇诡的公式，查询值为1，查询范围为0/(B3:B9=H3)，Why？

2、Lookup函数的特点：当在查询范围中找不到需要查询的值时，Lookup函数就会进行匹配，原则是用小于查询值的最大值进行替代查询值。

3、当B3:B9=H3成立时，返回True，暨1，不成立时返回False，暨0，而0/0则返回错误，所已查询范围就变成了一个由0和1组成的新数组，Lookup进行向下最大值匹配，从而返回0对应位置上的值。

4、多条件查询。

目的：查询销售员在相应地区的销量。

方法：

在目标单元格中输入公式：=IFERROR(LOOKUP(1,0/((B3:B9=H3)*(E3:E9=I3)),D3:D9),"无销量")。

解读：

多条件查询和单条件查询的原理是相同的，当两个或多个条件都成立时，返回True，暨1，否则返回False，暨0。

二、Index+Match组合函数。

1、单列查询。

目的：查询销售员对应的销量。

方法：

在目标单元格中输入公式：=INDEX(D3:D9,MATCH(H3,B3:B9,0))。

解读：

1、Index函数的作用为：返回给定的单元格区域中，行列交叉处的值或引用。语法结构：=Index(区域，行，[列])。当省略“列”时，默认为第1列。

2、Match函数的作用是：返回指定值在指定范围内的相对位置。语法结构：=Match(定位置，定位范围，匹配模式)。其中“1”为：小于；“0”为精准；“-1”为：大于。

2、多列查询。

目的：返回销售员对应的所有信息。

方法：

在目标单元格中输入信息：=INDEX($C$3:$E$9,MATCH($B$13,$B$3:$B$9,0),MATCH(C$12,$C$2:$E$2,0))。

解读：

利用Match函数定位目标值所在的行和列，然后用Index提取。

上述就是Excel中最典型的3个查询引用技巧，希望对大家有所帮助哦！

if函数引用条件？

if函数：逻辑判断函数

logical_test：条件表达式的结果，结果只有两种，对和错

value_if_true：当条件表达式为正确时候返回的值

value_if_false：当条件表达式为错误时候返回的值

一、IF函数

作用：根据条件进行判断并返回不同的值。

示例：

1、如果A1单元格值大于100，显示“完成”，否则显示“未完成”

=IF(A1>100,"完成","未完成")

2、判断成绩

=IF(A1<60,"不及格",IF(A1<80,"良好","优秀"))

3、如果A1的值大于60并且B1不为空，显示“已结束”否则显示“未结束”

=IF(AND(A1>60,B1<>""),"已结束","未结束")

二、IFerror函数

作用：把错误值显示为指定的内容

示例:

1、如果A1/B1返回错误值，则显示空

=Iferror(a1/b1,"")

2、如果Vlookup查找不到值，则显示空

=Iferror(vlookup(省略),"")

三、CountIF函数

作用：根据条件统计个数

示例：

1、计算A列有多少财务部的人员

=Countif(a:a,"财务部")

2、计算A列有多少个包括“北京”的公司名称

=Countif(a:a,"*北京*)

四、SumIF函数

作用：根据条件求和

1、统计C列大于1000的销售金额之和

=Sumif(c:c,">1000")

2、统计A列产品为“三星”所对应B列的销售个数

=Sumif(a:a,"三星",b:b)

五、CountIFs函数

作用：多条件计数

示例：

1、公司1的人事部有多少人(A列公司名称，B列部门名称)

=COUNTIFS(A2:A11,"公司1",B2:B11,"人事部")

2、工资在3000~4000之间的有多少人(D列为工资)

=COUNTIFS(D2:D11,">3000",D2:D11,"<4000")

六、SumIFs函数

作用：多条件求和

示例：

1、公司1人事部工资和(A列公司名称，B列部门名称。D列工资)

=SUMIFS(D2:D11,A2:A11,"公司1",B2:B11,"人事部")

2、A列为"电视"，B列包括34的C列数量之和

=Sumifs(C:C,A:A,"电视",b:b,"*34*")

七、AverageIF函数

作用：根据条件计算平均数

示例：

1、计算C列单价小于10的平均单价。

=AVERAGEIF(C:C,"<10")

2、计算C产品的平均单价(A列为产品名称)

=AVERAGEIF(A:A,"C",B:B)

八、AverageIFs函数

作用：多条件计算平均值

示例：

1、计算甲公司，经理级的平均工资(A列公司名，B列职称，C列工资金额)

=AVERAGEIFS(D2:D11,A2:A11,"甲公司",B2:B11,"经理")

2、统计工资在4000~8000之间的平均工资

=AVERAGEIFS(D2:D11,D2:D11,">4000",D2:D11,"<8000")

怎么知道什么时候用什么函数？

1、常用求和函数包括

①sum：简单累加，例如求3+2的值；

②sumif：根据单个条件求和，例如在1-10的整数中计算小于5的整数之和；

③sumifs：根据多个条件求和，例如在1-10的整数中计算小于5且大于2的整数之和；

2、常用求平均数函数包含

①average：对所有值求平均数，例如求2、5、7三个数的平均数。

②averageif：根据单个条件求平均数，例如求1-10的整数中偶数的平均数。

③averageifs：根据多个条件求平均数，例如求1-10的整数中小于7的偶数的平均数。

3、常用求单元格个数函数包含

①count：计算区域中包含数字的单元格个数，不包含其他。

②counta：计算区域中非空单元格个数，只有单元格内有内容即计算，不仅仅包含数字，标点符号都可以。

③countblank：是counta函数的反面应用，计算区域中空白单元格个数。

④countif：计算区域中满足单个条件的单元格个数。

⑤countifs：计算区域中满足多个条件的单元格个数。

4、常用四舍五入函数包括

①round：根据指定位数四舍五入，例如6.385四舍五入不保留小数点的值为6。

②roundup：向上舍入，不遵循四舍五入规则，例如6.385对应值为7。

③rounddown：向下舍入，不遵循四舍五入规则，例如6.385对应值为6。

④int：向下取整为最接近的整数，与rounddown类似。

5、常用比较大小的函数包括

①max：求区域中最大值。

②min：求区域中最小值。

最后补充一个分类汇总函数subtotal，它是复合函数，包含求和、计算平均数等11个函数，支持筛选或隐藏情况下计算。加上subtotal，常用的数据计算函数是18个，掌握这些函数，就可以应对九成以上数据计算方面的问题了。

excel如何在多项数据中筛选并求平均数？

方法/步骤

1、首先打开excel表格。

2、假设要求的是一班平均值。

3、输入公式=AVERAGEIF(D2:D8,"一班",C2:C8)。

4、按回车后出现结果。

5、手动找到符合的数据，发下结果是一样的。

6、注意:如果是没有条件的平均值的话，选中数据后，直接点击平均值。